'
' VBScript for ActiveX related features detection
'

' Determines whether ActiveX controls are enabled in browser
function AXEnabled()
	on error resume next
	activex = (NOT IsNull(CreateObject("ScriptBridge.ScriptBridge")))
	activex2 = (NOT IsNull(CreateObject("MSComctlLib.Slider")))
	activex3 = (NOT IsNull(CreateObject("ScriptBridge.ScriptBridge.1")))
	if (activex OR activex2 OR activex3) then
		AXEnabled = true
	else
		AXEnabled = false
	end if
end function

' Determines whether FlashPlayer ActiveX control is installed
function AXFlashExists()
	on error resume next
	vTest = false
	Set FlashObject = CreateObject("ShockwaveFlash.ShockwaveFlash")
	vTest = (NOT IsNull(FlashObject.IsPlaying()))
	if (vTest) then
		AXFlashExists = true
	else
		AXFlashExists = false
	end if
	Set FlashObject = Nothing
end function

' Try to create Flash player object with specified version
' and obtain exact version from the object
function AXFlashTryGetVersion(version)
        on error resume next
        Dim swControl, swVersion
        swVersion = 0
        
        set swControl = CreateObject("ShockwaveFlash.ShockwaveFlash." + CStr(version))
        if (IsObject(swControl)) then
          swVersion = swControl.GetVariable("$version")
        end if
	set swControl = Nothing
        AXFlashTryGetVersion = swVersion
end function

' Determines whether Atlantic Link ActiveX helper is installed
function AXHelperExists()
	Err.Clear
	On Error Resume Next
	Set axObject = CreateObject("FlashHelper.KbdFilter")
	If Err.Number = 0 then 
		AXHelperExists = true
	Else 
		AXHelperExists = false
	End If
	Set axObject = Nothing
end function

' Try to create Atlantic Link FlashHelper object with specified version
function AXFlashHelperTryGetVersion(version)
        on error resume next
        Dim axControl, axVersion
        axVersion = 0
        
        set axControl = CreateObject("FlashHelper.KbdFilter." + CStr(version))
        if (IsObject(axControl)) then
		if version > 1 then
			axVersion = axControl.Version
		end if
        end if
	set axControl = Nothing
        AXFlashHelperTryGetVersion = axVersion
end function